home *** CD-ROM | disk | FTP | other *** search
/ The Atari Compendium / The Atari Compendium (Toad Computers) (1994).iso / files / prgtools / gnustuff / tos / 881 / src6.zoo / _divdf3.s < prev    next >
Encoding:
Text File  |  1991-09-24  |  1.2 KB  |  63 lines
  1. # double precision floating point stuff for Atari-gcc using the SFP004
  2. # developed with gas
  3. #
  4. # double precision division
  5. #
  6. # M. Ritzert (mjr at dmzrzu71)
  7. #
  8. # 4.10.1990
  9. #
  10. # no NAN checking implemented since the 68881 treats this situation "correctly",
  11. # i.e. according to IEEE
  12.  
  13. # addresses of the 68881 data port. This choice is fastest when much data is
  14. # transferred between the two processors.
  15.  
  16. comm =     -6
  17. resp =    -16
  18. zahl =      0
  19.  
  20. # waiting loop ...
  21. #
  22. # wait:
  23. # ww:    cmpiw    #0x8900,a0@(resp)
  24. #     beq    ww
  25. # is coded directly by
  26. #    .long    0x0c688900, 0xfff067f8
  27.  
  28.     .even
  29. LC0:
  30.     .ascii "floating point division by 0\12\15\0"
  31.  
  32.     .text
  33.     .even
  34.     .globl    __divdf3, ___divdf3
  35.  
  36. __divdf3:
  37. ___divdf3:
  38.     tstl    a7@(12)            | check if divisor is 0
  39.     bne    continue
  40.     tstl    a7@(16)
  41.     bne    continue
  42.     moveml    d0-d7/a0-a6,a7@-
  43.     pea    LC0
  44.     movew    #9,a7@-
  45.     trap    #1
  46.     addql    #6,a7
  47.     moveml    a7@+,d0-d7/a0-a6
  48. continue:
  49.     lea    0xfffa50,a0
  50.     movew    #0x5400,a0@(comm)    | load first argument to fp0
  51.     cmpiw    #0x8900,a0@(resp)    | check
  52.     movel    a7@(4),a0@
  53.     movel    a7@(8),a0@
  54.     movew    #0x5420,a0@(comm)
  55.     .long    0x0c688900, 0xfff067f8
  56.     movel    a7@(12),a0@
  57.     movel    a7@(16),a0@
  58.     movew    #0x7400,a0@(comm)    | result to d0
  59.     .long    0x0c688900, 0xfff067f8
  60.     movel    a0@,d0
  61.     movel    a0@,d1
  62.      rts
  63.